Excel WENN Funktion: bedingte Ausführung

Excel Insights: Mit der Excel WENN Funktion die Ausführung unter den Eintritt einer Bedingung stellen

Die Excel WENN Funktion ist das Kernstück der Logischen Funktionen. Sie macht die Ausführung weiterer Formeln und Funktionen von dem Eintritt oder dem Nichteintritt einer Bedingung abhängig.

Häufig müssen wir Entscheidungen treffen. A oder B? Bekommt Sarah dieses Jahr einen Bonus ausgezahlt oder nicht? Kann die Kaltfließpresse im Januar angeschafft werden? Ja oder Nein?

In der Regel treffen wir diese Entscheidungen nicht aus dem Bauch heraus, sondern anhand objektiver Kriterien. Die stehen ebenso wie die daraus abzuleitenden Handlungen meistens bereits von vornherein fest. So ist es auch in unseren Beispielen mit der Bonuszahlung oder der Investitionsentscheidung. Es bleibt also nur die Frage, ob die Kriterien erfüllt wurden.

Hat Sarah dieses Jahr mindestens 20 Neukunden gewonnen oder einen Umsatz in Höhe von über 120.000 EUR erzielt? Konnte ein Jahresüberschuss von 700.000 EUR erzielt werden und sind im Januar 220.000 EUR liquide Mittel für die Anzahlung der Presse frei?

Die Excel WENN Funktion übernimmt die Überprüfung dieser Kriterien bzw. Bedingungen, beantwortet sie mit Ja oder Nein und entscheidet sich dann für eine der beiden vordefinierten Rückgabewerte.


Übersicht

  1. Excel WENN Funktion: Syntax und Funktionsweise
  2. Beispiele zur WENN DANN Funktion
    1. Ein Wert vom Typ Zahl als Bedingung
    2. Excel WENN Funktion mit Text
    3. Eine Logische Funktion als Bedingung
    4. Excel WENN Funktion mit Datum
  3. Die Verknüpfung von Bedingungen
    1. WENN Funktion mit ODER Verknüpfung
    2. UND Verknüpfung: Wenn Funktion mit 2 Bedingungen
    3. Excel WENN Funktion verschachtelt: mehr als 2 Optionen
  4. Zusammenfassung
  5. Ressourcen

1. Excel WENN Funktion: Syntax und Funktionsweise

Einfach gesagt, überprüft die Excel WENN Funktion Bedingungen und gibt dann je nach Ergebnis Option A oder Option B zurück. In der Informatik werden diese Entscheidungsbäume als Flussdiagramm dargestellt:

Excel Insights: Flussdiagramm aus der Informatik zeigt Entscheidungsweg bei Bedingungen und der Excel WENN Funktion
Ein Flussdiagramm verdeutlicht die Funktionsweise der Excel WENN Funktion

Die Syntax der Funktion WENN gestaltet sich wie folgt:

=WENN(Wahrheitstest;[Wert_wenn_wahr];[Wert_wenn_falsch])
  • Wahrheitstest
    Ein Wahrheitstest ist eine logische Aussage, die je nachdem ob die Aussage richtig ist, einen der beiden Wahrheitswerte WAHR oder FALSCH zurückgibt. Detaillierte Informationen zum Wahrheitstest sowie eine Auflistung der logischen Operatoren liefert der Artikel Excel Bedingungen WAHR oder FALSCH.
  • [Wert_wenn_wahr]
    Der [Wert_wenn_wahr] ist der Rückgabewert der WENN Funktion, wenn der Wahrheitstest den Wahrheitswert WAHR zurückgibt. Der Rückgabewert kann ein Text, ein Datum, ein logischer Wert oder eine Zahl sein, wobei natürlich auch Formeln, Funktionen und Zellbezüge möglich sind.
  • [Wert_wenn_falsch]
    Der [Wert_wenn_falsch] ist entsprechend der Rückgabewert der WENN Funktion, wenn der Wahrheitstest den Wahrheitswert FALSCH zurückgibt. Er kann ebenfalls ein Text, ein Datum, ein logischer Wert, eine Zahl sein oder auch aus Formeln, Funktionen und Zellbezügen bestehen.

Umgangsprachlich könnte man die Syntax auch so formulieren:

=WENN(BEDINGUNG;DANN;SONST)

Das erklärt auch, warum auch oft von der „Excel WENN DANN Funktion“ gesprochen wird.


2. Beispiele zur Excel WENN Funktion

Hier findest du vier Beispiele für Bedingungen mit unterschiedlichem Datentyp:


2.1 Ein Wert vom Typ Zahl als Bedingung

Beginnen wir mit einem einfachen Beispiel. Das Jahresergebnis ist eine Zahl. Je nachdem, ob es unternehmerisch ein erfolgreiches oder ein weniger erfolgreiches Jahr war, kann das Jahresergebnis entweder positiv oder aber auch negativ ausfallen. Ein positives Jahresergebnis bedeutet einen Jahresüberschuss, ein negatives Jahresergebnis bedeutet – elegant ausgedrückt – einen Jahresfehlbetrag.

Du kannst nun die WENN Funktion benutzen, um zu überprüfen ob es sich bei deinem Jahresergebnis um einen Jahresüberschuss oder einen Jahresfehlbetrag handelt und dir einen darauf bezogenen Textbaustein dynamisch ausgeben lassen:

Excel Insights: WENN Funktion mit Zahl
Die WENN Funktion überprüft, ob die Zahl positiv oder negativ ist.

Die Formel in de Zelle B6 lautet:

=WENN(B5>0;"Im Jahr 2018 wurde ein Jahresüberschuss erwirtschaftet.";"Im Jahr 2018 wurde leider ein Jahresfehlbetrag erwirtschaftet.")

Der Wahrheitstest überprüft, ob B5>0 ist, also ob das Jahresergebnis positiv ist. WENN B5 positiv ist, DANN wird der Text „Im Jahr 2018 wurde ein Jahresüberschuss erwirtschaftet.“ ausgegeben, SONST wird der Text „Im Jahr 2018 wurde leider ein Jahresfehlbetrag erwirtschaftet.“ ausgegeben.

WICHTIG: Soll die WENN Funktion in einem Rückgabewert Text ausgeben, der direkt in der Funktion angegeben wird, muss er in Anführungszeichen „“ gesetzt werden.

Sowohl die Bedingung als auch die Rückgabewerte müssen nicht direkt in der WENN Funktion angegeben werden, sie können auch über Zellbezüge referenziert werden:

Excel Insights: Zellbezüge anstatt Text
WENN Funktion mit Bedingung Zahl und Zellbezügen

Die Formel in der neuen Ausgabezelle B6 lautet:

=WENN(B5>B10;B11;B12)

WENN der Wert in Zelle B5 größer als der Wert in Zelle B10 ist, DANN wird der Wert in Zelle B11 ausgegeben, SONST wird der Wert in Zelle B12 ausgegeben.

In der Zelle B10 steht die Zahl 0 und ermöglicht so die gleiche Prüfung wie zuvor. In den Zellen B11 und B12 sind die identischen Texte enthalten, die zuvor mit Anführungsstrichen „“ direkt in der Funktion angegeben wurden.


2.2 Excel WENN Funktion mit Text

Mit der WENN Funktion kannst du auch überprüfen, ob Texte oder Textteile übereinstimmen. Dabei kann der abzugleichende Text wieder als Zellbezug angegeben werden oder aber auch direkt in der Funktion stehen.

In unserem Beispiel exportiert ein Mittelständler mittlerweile auch nach Frankreich. Die Geschäfte gehen gut, Umsatz und Gewinn steigen. Da der Unternehmer ein weiser, vorausschauender Mann ist, ist ihm klar, dass auch die Lebenserhaltungskosten steigen. Gerade in Paris, wo man über die Wohnungspreise in Berlin nur müde lächeln kann.

Bevor ihm sein tatkräftiges Personal davon läuft, entscheidet er also, allen in Paris wohnhaften Angestellten leistungsunabhängig einen monatlichen Zuschlag i.H.v. 500 EUR zu gewähren:

Excel Insights: Gehaltszuschlag mit WENN Funktion
Gehaltszuschlag aufgrund von Wohnort per WENN Funktion und Textabgleich

Die Formel in der Zelle E7 lautet:

=WENN(C7="Paris";500;0)

WENN der Wert in der Zelle C7 dem Text „Paris“ entspricht, DANN gibt es 500 EUR Zuschlag, SONST gibt es nichts.

WICHTIG: Wenn du den Text direkt in der Funktion angibst, dann muss er immer in Anführungszeichen „“ stehen.

Natürlich hätte man sich die Spalte E auch sparen können und das Gesamtgehalt direkt in der Spalte F ausgeben können. Die Formel für die Zelle F7 lautet dann:

=WENN(C7="Paris";D7+500;D7) 

WENN der Wert in der Zelle C7 dem Text „Paris“ entspricht, DANN gebe die Summe aus dem Wert in Zelle D7 und 500 EUR zurück, sonst nur den Wert aus der Zelle D7.


2.3 Eine Logische Funktion als Bedingung

Es gibt auch einige Funktionen, die als Rückgabewert WAHR oder FALSCH ausgeben. Auch sie können in einer WENN Funktion als Bedingungen angegeben werden. Dabei ist es egal, ob sie direkt in der WENN Funktion oder über einen Zellbezug angegeben werden.

In dem Beispiel fragen wir eine Tabelle mit dem SVERWEIS ab, der gesuchte Wert aus der Zelle B5 ist jedoch nicht in dem zu durchsuchenden Zellbereich A11:A17 enthalten. Der Rückgabewert der Funktion SVERWEIS ist daher #NV:

Excel Insights: WENN Funktion mit Logischer Funktion als Bedingung
Auch eine Logische Funktion kann innerhalb einer WENN Funktion Wahrheitstest sein.

Das ist unschön, weil mit dem #NV Fehler nicht weitergerechnet werden kann. Alle folgenden Berechnungen wären damit unmöglich, da sie den #NV Fehler übernehmen. Schöner wäre es also wenn das Suchkriterium nicht gefunden werden kann, einfach die Zahl 0 auszugeben. Damit kann man weiterrechnen.

An dieser Stelle kommt die Funktion ISTNV ins Spiel. Ich werde ihr noch einen gesonderten Artikel spendieren. Hier reicht aber eine kurze Erklärung am Beispiel. Wir passen die SVERWEIS Funktion in der Zelle B6 wie folgt an:

=ISTNV(SVERWEIS($B$6;$A$11:$C$17;2;0))

Die Funktion ISTNV ist ein Wahrheitstest und gibt bei einem #NV Fehler den Wert WAHR zurück. Da der SVERWEIS einen #NV Fehler ausgibt, ist das aktuelle Ergebnis in der Zelle B6 jetzt WAHR anstatt #NV.

Im nächsten Schritt setzen wir den Wahrheitstest noch mit zwei Optionen in eine WENN Funktion ein:

=WENN(ISTNV(SVERWEIS($B$6;$A$11:$C$17;2;0));0;SVERWEIS($B$6;$A$11:$C$17;2;0))

WENN die ISTNV Funnktion WAHR ist weil der SVERWEIS den #NV Fehler zurückgibt, DANN gib die Zahl 0 zurück, SONST gib den Rückgabewert vom SVERWEIS zurück.

Die SVERWEIS Funktion ist also innerhalb der ISTNV Funktion einmal Teil der Bedingung der WENN Funktion und gleichzeitig auch noch einmal der zweite Rückgabbwert der WENN Funktion. Es klingt komplizierter als es ist. Schau dir einfach unten bei den Ressourcen die Beispiele in der Arbeitsmappe an.

HINWEIS: Ich empfehle anstatt der Kombination aus den Funktionen WENN und ISTNV in der Regel die Funktion WENNNV.


2.4 Excel WENN Funktion mit Datum

Natürlich kannst du mit der Excel WENN Funktion auch Datumswerte abgleichen. In einem Dienstplan sind die fortlaufenden Daten in Spalte A und die Namen der Diensthabenden in Spalte B organisiert. In Zelle E2 steht in Form der Funktion HEUTE immer das tagesaktuelle Datum. In Spalte D wird geprüft, wer an diesem Tag Küchendienst hat:

Die Formel in Zelle D4 lautet:

=WENN(A4=$E$2;B4&" hat heute Küchendienst";"")

Der Wahrheitstest überprüft, ob die Daten in den Zellen A4 und $E$2 übereinstimmen. Nur wenn das der Fall ist, wird der Text in der Spalte D ausgegeben. Dazu wird der dem Namen in Spalte A über das Und-Zeichen & mit dem Text “ hat heute Küchendienst“ verknüpft. Sonst werden zwei Anführungszeichen „“ für einen Text ohne Inhalt (sprich nichts) ausgegeben.

WICHTIG: Du kannst Datumswerte anders als Zahlen, Texte oder Wahrheitswerte nicht direkt in den Wahrheitstest schreiben, sondern musst immer mit Zellbezügen arbeiten. Wenn du die WENN Funktion aus der Zelle D4 anschließend auch in den Zellbereich D5:D11 kopieren willst, musst du die Zelle mit dem heutigen Datum E2 mit den Dollar-Zeichen $ als absolute Bezüge angeben.


3. Die Verknüpfung von Bedingungen

Oft sind die mit der WENN Funktion zu prüfenden Sachverhalte jedoch deutlich komplexer. Es reicht nicht aus, nur eine Bedingung zu prüfen. In diesem Fall kann WENN auch mit mehreren Bedingungen umgehen. Folgende drei Szenarien sind denkbar:


3.1 WENN Funktion mit ODER Verknüpfung

Ist die Erfüllung einer von mehreren Bedingungen ausreichend, kannst du mit Hilfe der ODER Funktion mehrere Wahrheitstests miteinander verknüpfen. Wenn ein Wahrheitstest als Rückgabewert WAHR liefert, liefert die ODER Funktion als Rückgabewert ebenfalls den Rückgabewert WAHR und die WENN Funktion liefert entsprechend als Rückgabewert den [Wert_wenn_wahr].

Im Eingangsbeispiel mit der Bonuszahlung musste Sarah entweder mindestens 20 Neukunden oder einen Jahresumsatz von 120.000 EUR schaffen. Schon am Wortlaut wird die notwendige ODER Verknüpfung deutlich. Eine der beiden Bedingungen muss WAHR sein:

Excel Insights: Excel WENN Funktion mit ODER Funktion verknüpft
Excel WENN Funktion mit ODER Funktion verknüpft 2 Bedingungen

Die Formel zur Überprüfung der Sonderzahlung in Zelle E4 lautet:

=WENN(ODER(B4>=20;C4>=120000);"Bonuszahlung";"keineBonuszahlung")
  • Eine ODER Funktion umschließt die beiden Wahrheitstests für die Bonuszahlung:
    • B4>=20
    • C4>=120000
  • Als [Wert_wenn_wahr] soll „Bonuszahlung“ ausgegeben werden.
  • Als [Wert_wenn_falsch] soll „keine Bonuszahlung“ ausgegeben werden.

HINWEIS: Für detaillierte Informationen und weitere Beispiele empfehle ich dir den Artikel zur Excel ODER Funktion.


3.2 UND Verknüpfung: Wenn Funktion mit 2 Bedingungen

Ist die Erfüllung jeder einzelnen Bedingungen notwendig, kannst du mit der UND Funktion die notwendigen Wahrheitstests miteinander kombinieren. Nur wenn jeder einzelne Wahrheitstest als Rückgabewert WAHR liefert, liefert auch die UND Funktion als Rückgabewert WAHR und nur dann liefert auch die WENN Funktion als Rückgabewert den [Wert_wenn_wahr].

Im zweiten Eingangsbeispiel geht es um die Anschaffung eine Kaltfließpresse, die nur erfolgen kann wenn der Jahresüberschuss mindestens 700.000 EUR beträgt und zusätzlich auch im Januar 220.000 EUR liquide Mittel für den nicht von der Bank finanzierten Teil der Kaufpreiszahlung zur Verfügung stehen. Auch hier weist der Wortlaut schon auf die UND Funktion hin. Beide Bedingungen müssen WAHR sein:

Excel Insights: WENN Funktion mit 2 Bedingungen und UND Funktion
Mit der UND Funktion die WENN Funktion mit 2 Bedingungen ausführen

Die Formel zur Überprüfung der Sonderzahlung in Zelle D9 lautet:

=WENN(UND(D5>=700000;D7>=220000);"Kalfließpresse";"keine Kaltfließpresse")
  • Eine UND Funktion umschließt die beiden Wahrheitstests für die Kaltfließpresse:
    • D5>=700000
    • D7>=220000
  • Als [Wert_wenn_wahr] soll „Kaltfließpresse“ ausgegeben werden.
  • Als [Wert_wenn_falsch] soll „keine Kaltfließpresse“ ausgegeben werden.

HINSWEIS: Für detaillierte Informationen und weitere Beispiele empfehle ich dir den Artikel zur Excel UND Funktion.


3.3 Excel WENN Funktion verschachtelt: mehr als 2 Optionen

Eine andere Art der Verknüpfung ist notwendig, wenn es mehr als zwei Optionen, also nicht nur die Rückgabewerte [Wert_wenn_wahr] und [Wert_wenn_falsch] gibt. In diesem Fall kannst du mehrere WENN Funktionen ineinander verschachteln.

Die erste WENN Funktion kann z.B. als Rückgabewert ihren eigenen [Wert_wenn_wahr] und anstelle ihres [Wert_wenn_falsch] den Rückgabewert einer zweiten WENN Funktion und damit deren mögliche Rückgabewerte [Wert_wenn_wahr] oder [Wert_wenn_falsch] zurückgeben.

Ist die Anschaffung der Kaltfließpresse keine Option mehr, betragen Jahresüberschuss und liquide Mittel aber mindestens 60.000 EUR, ist noch einneuer Firmenwagen für den Geschäftsführer drin:

Excel Insights: Excel WENN Funktion verschachtelt für 3 Optionen
Zwei verschachtelte Wenn Funktionen für mehr asl 2 Optionen

Anders als im Beispiel unter Punkt 3.2 lautet die Formel in D9:

=WENN(UND(D5>=700000;D7>=220000);"Kalfließpresse";WENN(UND(D5>=60000;D7>=60000);"Firmenwagen";"gar nichts"))

Die erste WENN Funktion ist wie folgt aufgebaut:

  • Eine UND Funktion umschließt die beiden Wahrheitstests für die Kaltfließpresse:
    • D5>=700000
    • D7>=220000
  • Als [Wert_wenn_wahr] soll „Kaltfließpresse“ ausgegeben werden.
  • Als [Wert_wenn_falsch] folgt die zweite WENN Funktion.

Werden die beiden Bedingungen für die Kaltfließpresse erfüllt, wird als [Wert_wennwahr] das Wort „Kaltfließpresse“ ausgegeben. Sonst wird als [Wert_wenn_falsch] der Rückgabewert der zweiten WENN Funktion ausgegeben:

  • Auch hier umschließt eine UND Funktion die beiden Wahrheitstests für den Firmenwagen:
    • D5>=60000
    • D7>=60000
  • Als [Wert_wenn_wahr] soll „Firmenwagen“ ausgegeben werden.
  • Als [Wert_wenn_falsch] soll „gar nichts“ausgegeben werden.

Die Kaltfließpresse ist vom Tisch. Werden die beide Bedingungen für den Firmenwagen jedoch erfüllt, wird als [Wert_wennwahr] der Text „Firmenwagen“ ausgegeben. Sonst wird als [Wert_wenn_falsch] der Text „gar nichts“ ausgegeben.


4. Zusammenfassung

Die WENN Funktion überprüft logische Aussagen und gibt abhängig vom Wahrheitswert einen der beiden definierten Rückgabewerte aus. Die Syntax lässt sich einfach merken: WENN DANN SONST. Du kannst mit ihr also Berechnungen von der Erfüllung einer Bedingung abhängig machen.


5. Ressourcen


Kommentar verfassen

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.


Die im Rahmen der Kommentarfunktion übermittelten Daten werden gespeichert. Weitere Informationen zur Datenverarbeitung findest du in der Datenschutzerklärung.